[原创]一些与平台基本无关的图像函数～

Eastsun · 发表于 2005-1-10 19:01:00

;****************************************
;函数说明:
;GetxyIndex:取得点(x,y)所在Ram地址送$80,$81,所在位送X
;位标记送A,使用并影响$80,$81,$fe,a,x,y
; 入参:当 A置0时为屏幕状态,否则为缓存状态
;GetPoint:  取得点(x,y)的状态,清除则A置0,否则非零
; 入参:当 A置0时为屏幕状态,否则为缓存状态
;PutPoint:  画点
GraphData:
.db $c0,$79,$d4,$79,$e8,$79,$fc,$79,$10,$7a,$24,$7a,$38,$7a,$4c,$7a
.db $60,$7a,$74,$7a,$88,$7a,$9c,$7a,$b0,$7a,$c4,$7a,$d8,$7a,$ec,$7a
.db $00,$7b,$14,$7b,$28,$7b,$3c,$7b,$50,$7b,$64,$7b,$78,$7b,$8c,$7b
.db $a0,$7b,$b4,$7b,$c8,$7b,$dc,$7b,$f0,$7b,$04,$7c,$18,$7c,$2c,$7c
.db $40,$7c,$54,$7c,$68,$7c,$7c,$7c,$90,$7c,$a4,$7c,$b8,$7c,$cc,$7c
.db $e0,$7c,$f4,$7c,$08,$7d,$1c,$7d,$30,$7d,$44,$7d,$58,$7d,$6c,$7d
.db $80,$7d,$94,$7d,$a8,$7d,$bc,$7d,$d0,$7d,$e4,$7d,$f8,$7d,$0c,$7e
.db $20,$7e,$34,$7e,$48,$7e,$5c,$7e,$70,$7e,$84,$7e,$98,$7e,$ac,$7e
.db $c0,$7e,$d4,$7e,$e8,$7e,$fc,$7e,$10,$7f,$24,$7f,$38,$7f,$4c,$7f
.db $60,$7f,$74,$7f,$88,$7f,$9c,$7f,$b0,$7f,$c4,$7f,$d8,$7f,$ec,$7f
AslData:
.db $80,$40,$20,$10,$08,$04,$02,$01
;******************************************
GetxyIndex:

      PHA
      TXA
      STA $fe    ;保存X
      PHA
      TYA
      ASL
      TAX
      LDA GraphData,x
      STA $80
      LDA GraphData+1,x
      STA $81
      PLA
      LSR
      LSR
      LSR
      CLC
      ADC $80
      STA $80
      BCC GetxyIndexLable1
      INC $81
GetxyIndexLable1:
      PLA
      BNE GetxyIndexBuff
      LDA $80
      SEC
      SBC #$00
      STA $80
      LDA $81
      SBC #$60             ;此处值与具体的机型有关！！
      STA $81
      JMP GetxyIndexLable2
GetxyIndexBuff:
      LDA $80
      SEC
      SBC #$00
      STA $80
      LDA $81
      SBC #$40
      STA $81
GetxyIndexLable2:
      LDA $fe
      AND #$07
      TAX
      LDA AslData,x
      RTS

Eastsun · 发表于 2005-1-10 19:01:00

;***************************
GetPoint:
      CPX #$a0
      BCS GetPointReturn
      CPY #$50
      BCS GetPointReturn
      JSR GetxyIndex
      LDY #$00
      AND ($80),y
GetPointReturn:
      RTS

Eastsun · 发表于 2005-1-10 19:02:00

;***************************
PutPoint:
      CPX #$a0
      BCS PutPointReturn
      CPY #$50
      BCS PutPointReturn
      JSR GetxyIndex
      PHA
      LDA $3007
      LDY #$00
      AND #$03
      CMP #$00
      BEQ PutPoint0
      CMP #$01
      BEQ PutPoint1
      PLA
      EOR ($80),y
      STA ($80),y
      RTS
PutPoint0:
      PLA
      EOR #$00
      AND ($80),y
      STA ($80),y
      RTS
PutPoint1:
      PLA
      ORA ($80),y
      STA ($80),y
PutPointReturn:
      RTS

Eastsun · 发表于 2005-1-10 19:03:00

;**************************************
;函数说明:将缓存数据刷新到屏幕
;函数用到$80~$83,$3007为1或2
;**************************************
RefreshScreen:
      LDA #<Buff
      STA $80
      LDA #>Buff
      STA $81
      LDA #<Graph
      STA $82
      LDA #>Graph
      STA $83
      LDX #$06
      LDY #$00
      LDA $3007
      CMP #$01
      BNE RefreshScreen2
RefreshScreenLoop1:
      LDA ($80),y
      STA ($82),y
      INY
      BNE RefreshScreenLoop1
      INC $81
      INC $83
      DEX
      BNE RefreshScreenLoop1
      LDY #$3f
RefreshScreenLoop2
      LDA ($80),y
      STA ($82),y
      DEY
      BPL RefreshScreenLoop2
      RTS
RefreshScreen2:
RefreshScreenLoop3
      LDA ($80),y
      EOR #$ff
      STA ($82),y
      INY
      BNE RefreshScreenLoop3
      INC $81
      INC $83
      DEX
      BNE RefreshScreenLoop3
      LDY #$3f
RefreshScreenLoop4
      LDA ($80),y
      EOR #$ff
      STA ($82),y
      DEY
      BPL RefreshScreenLoop4
      RTS

Eastsun · 发表于 2005-1-10 19:04:00

;*****************************************
;函数说明:做一x1=x2的直线段
;函数使用并改变$80,$81,a,x,y,$3000~$3003
;*****************************************
LineXOverFlow1:
      LDA #$4f
      STA $3001
      JMP LineXXX1
LineXOverFlow2:
      LDA #$4f
      STA $3003
      JMP LineXXX2
LineXReturn:
      PLA
      STA $85
      PLA
      STA $84
LineXReturn1:
      RTS

LineX:
      TAX
      LDA $3001
      CMP #$50
      BCS LineXOverFlow1
LineXXX1:
      LDA $3003
      CMP #$50
      BCS LineXOverFlow2
LineXXX2:
      LDA $3000
      CMP #$a0
      BCS LineXReturn1
      LDA $84
      PHA                   ;保护$84,$85的值
      LDA $85
      PHA
      STX $84
      LDA $3001
      CMP $3003
      BCC LineXLabel2
      TAX
      LDA $3003
      STA $3001
      STX $3003
LineXLabel2:
      LDX $3000
      LDY $3001
      LDA $84
      JSR GetxyIndex
      STA $84
      LDA $3003
      SEC
      SBC $3001
      STA $85             ;行数-1
      LDY #$00
      LDX #$00
      LDA $3007
      AND #$03
      CMP #$02
      BEQ LineXLabel02
      CMP #$01
      BEQ LineXLabel01
LineXLoop1:
      LDA $84
      EOR #$ff
      AND ($80),y
      STA ($80),y
      CLC
      LDA $80
      ADC #$14
      STA $80
      LDA $81
      ADC #$00
      INX
      CPX $85
      BCC LineXLoop1
      BEQ LineXLoop1
      JMP LineXReturn
LineXLabel02:
LineXLoop2:
      LDA $84
      EOR ($80),y
      STA ($80),y
      CLC
      LDA $80
      ADC #$14
      STA $80
      LDA $81
      ADC #$00
      STA $81
      INX
      CPX $85
      BCC LineXLoop2
      BEQ LineXLoop2
      JMP LineXReturn
LineXLabel01:
LineXLoop3:
      LDA $84
      ORA ($80),y
      STA ($80),y
      CLC
      LDA $80
      ADC #$14
      STA $80
      LDA $81
      ADC #$00
      STA $81
      INX
      CPX $85
      BCC LineXLoop3
      BEQ LineXLoop3
      JMP LineXReturn

Eastsun · 发表于 2005-1-10 19:05:00

;***************************************
;函数说明:做一y1=y2的直线段,使用并改变$80~$83
;$3000~$3003,a,x,y
;***************************************
LineYData1 .DB $ff,$7f,$3f,$1f,$0f,$07,$03,$01
LineYData2 .DB $80,$c0,$e0,$f0,$f8,$fc,$fe,$ff
LineYOverFlow1:
      LDA #$9f
      STA $3001
      JMP LineYYY1
LineYOverFlow2:
      LDA #$9f
      STA $3003
      JMP LineYYY2

LineYReturn:
      PLA
      STA $86
      PLA
      STA $85
      PLA
      STA $84
LineYReturn1:
      RTS
LineY:
      TAX
      LDA $3001
      CMP #$50
      BCS LineYReturn1
      LDA $3000
      CMP #$a0
      BCS LineYOverFlow1
LineYYY1:
      LDA $3002
      CMP #$a0
      BCS LineYOverFlow2
LineYYY2:
      LDA $84
      PHA
      LDA $85
      PHA
      LDA $86
      PHA
      STX $86             ;sav A in $86
      LDA $3000
      CMP $3002
      BCC LineYLabel1
      LDX $3002
      STX $3000
      STA $3002
LineYLabel1:
      LDA $86
      LDX $3002
      LDY $3003
      JSR GetxyIndex
      STX $85             ;注意:保存的是x
      LDA $80
      STA $82
      LDA $81
      STA $83
      LDA $86
      LDX $3000
      LDY $3001
      JSR GetxyIndex
      STX $84             ;***************
      LDA $80
      CMP $82
      BNE LineYLabel2
      LDA $81
      CMP $83
      BNE LineYLabel2
      LDX $84
      LDA LineYData1,x
      STA $84
      LDX $85
      LDA LineYData2,x
      AND $84
      TAX
      LDY #$00
      LDA $3007
      AND #$03
      CMP #$00
      BEQ LineYLabel00
      CMP #$01
      BEQ LineYLabel01
      TXA
      EOR ($80),y
      STA ($80),y
      JMP LineYReturn

LineYLabel00:
      TXA
      EOR #$ff
      AND ($80),y
      STA ($80),y
      JMP LineYReturn

LineYLabel01:
      TXA
      ORA ($80),y
      STA ($80),y
      JMP LineYReturn

;^^^^^^^^^^^^^^^^^^^^^^^^^
LineYLabel2:
      LDY #$00
      LDA $3007
      AND #$03
      CMP #$00
      BNE LineYLabel12
      LDX $84
      LDA LineYData1,x
      EOR #$ff
      AND ($80),y
      STA ($80),y
      LDX $85
      LDA LineYData2,x
      EOR #$ff
      AND ($82),y
      STA ($82),y
LineYLoop1:
      INC $80
      BNE LineYLabel3
      INC $81
LineYLabel3:
      LDA $81
      CMP $83
      BNE LineYLabel4
      LDA $80
      CMP $82
      BCC LineYLabel4
      JMP LineYReturn
LineYLabel4:
      LDA #$00
      STA ($80),y
      JMP LineYLoop1
LineYLabel12:
      CMP #$01
      BNE LineYLabel02
      LDX $84
      LDA LineYData1,x
      ORA ($80),y
      STA ($80),y
      LDX $85
      LDA LineYData2,x
      ORA ($82),y
      STA ($82),y
LineYLoop2:
      INC $80
      BNE LineYLabel5
      INC $81
LineYLabel5:
      LDA $81
      CMP $83
      BNE LineYLabel6
      LDA $80
      CMP $82
      BCC LineYLabel6
      JMP LineYReturn
LineYLabel6:
      LDA #$ff
      STA ($80),y
      JMP LineYLoop2
LineYLabel02:
      LDX $84
      LDA LineYData1,x
      EOR ($80),y
      STA ($80),y
      LDX $85
      LDA LineYData2,x
      EOR ($82),y
      STA ($82),y
LineYLoop3:
      INC $80
      BNE LineYLabel7
      INC $81
LineYLabel7:
      LDA $81
      CMP $83
      BNE LineYLabel8
      LDA $80
      CMP $82
      BCC LineYLabel8
      JMP LineYReturn
LineYLabel8:
      LDA #$ff
      EOR ($80),y
      STA ($80),y
      JMP LineYLoop3

Eastsun · 发表于 2005-1-10 19:06:00

;******************************************
;函数说明:画矩形
BoxReturn:
      PLA
      STA $84
      RTS
Box:
      TAX
      LDA $84
      PHA
      LDA $3000
      STA $3010
      LDA $3001
      STA $3011
      LDA $3002
      STA $3012
      LDA $3003
      STA $3013
      LDA $3007
      STA $3017
      LDA $3000          ;画左边直线
      STA $3002
      LDA $84
      JSR LineX
      LDA $3012          ;画右边直线
      CMP $3010
      BEQ BoxReturn
      STA $3000
      STA $3002
      LDA $3017
      STA $3007
      LDA $84
      JSR LineX
      LDA $3011
      STA $3001
      STA $3003
      LDA $3010
      CMP $3012
      BCC BoxLabel1
      STA $3002
      LDA $3012
      STA $3000
      JMP BoxLabel2
BoxLabel1:
      STA $3000
      LDA $3012
      STA $3002
BoxLabel2:
      INC $3000
      DEC $3002
      LDA $3002
      CMP $3000
      BCS BoxLabel3
      JMP BoxReturn
BoxLabel3:
      LDA $3013
      STA $3003
      STA $3001
      LDA $3017
      STA $3007
      LDA $84
      JSR LineY
      LDA $3011
      CMP $3013
      BNE BoxLabel4
      JMP BoxReturn
BoxLabel4:
      STA $3001
      STA $3003
      LDA $3017
      STA $3007
      LDA $84
      JSR LineY
      JMP BoxReturn

Eastsun · 发表于 2005-1-10 19:09:00

;*****************************************

;注意:该函数为了提高效率,求平方时用的是直接读取数据的方法

;这样会占用一些空间,而且这里对画的圆有一定要求:R<160

;如果谁有更好的算法,如果能告诉我，非常感谢～
;函数说明:画圆
;函数说明:求平方,入参A(<160).出参

80,$81
;函数说明:求两整型数的和(80,81)+(82,83)->(82,83)
;函数说明:比较($80,$81),($82,$83)的大小,前者大(or=):SEC,否则CLC
;*****************************************
PowerData1  .DB $00,$00,$01,$00,$04,$00,$09,$00,$10,$00,$19,$00,$24,$00,$31,$00,$40,$00,$51,$00
         .DB $64,$00,$79,$00,$90,$00,$A9,$00,$C4,$00,$E1,$00,$00,$01,$21,$01,$44,$01,$69,$01
         .DB $90,$01,$B9,$01,$E4,$01,$11,$02,$40,$02,$71,$02,$A4,$02,$D9,$02,$10,$03,$49,$03
         .DB $84,$03,$C1,$03,$00,$04,$41,$04,$84,$04,$C9,$04,$10,$05,$59,$05,$A4,$05,$F1,$05
         .DB $40,$06,$91,$06,$E4,$06,$39,$07,$90,$07,$E9,$07,$44,$08,$A1,$08,$00,$09,$61,$09
         .DB $C4,$09,$29,$0A,$90,$0A,$F9,$0A,$64,$0B,$D1,$0B,$40,$0C,$B1,$0C,$24,$0D,$99,$0D
         .DB $10,$0E,$89,$0E,$04,$0F,$81,$0F,$00,$10,$81,$10,$04,$11,$89,$11,$10,$12,$99,$12
         .DB $24,$13,$B1,$13,$40,$14,$D1,$14,$64,$15,$F9,$15,$90,$16,$29,$17,$C4,$17,$61,$18
         .DB $00,$19,$A1,$19,$44,$1A,$E9,$1A,$90,$1B,$39,$1C,$E4,$1C,$91,$1D,$40,$1E,$F1,$1E
         .DB $A4,$1F,$59,$20,$10,$21,$C9,$21,$84,$22,$41,$23,$00,$24,$C1,$24,$84,$25,$49,$26
         .DB $10,$27,$D9,$27,$A4,$28,$71,$29,$40,$2A,$11,$2B,$E4,$2B,$B9,$2C,$90,$2D,$69,$2E
         .DB $44,$2F,$21,$30,$00,$31,$E1,$31,$C4,$32,$A9,$33,$90,$34,$79,$35,$64,$36,$51,$37
         .DB $40,$38,$31,$39,$24,$3A,$19,$3B,$10,$3C,$09,$3D,$04,$3E
PowerData2  .DB $01,$3F,$00,$40,$01,$41
         .DB $04,$42,$09,$43,$10,$44,$19,$45,$24,$46,$31,$47,$40,$48,$51,$49,$64,$4A,$79,$4B
         .DB $90,$4C,$A9,$4D,$C4,$4E,$E1,$4F,$00,$51,$21,$52,$44,$53,$69,$54,$90,$55,$B9,$56
         .DB $E4,$57,$11,$59,$40,$5A,$71,$5B,$A4,$5C,$D9,$5D,$10,$5F,$49,$60,$84,$61,$C1,$62

Power:
         ASL
         TAX
         BCS PowerLabel
         LDA PowerData1,x
         STA $80
         LDA PowerData1+1,x
         STA $81
         RTS
PowerLabel:
         LDA PowerData2,x
         STA $80
         LDA PowerData2+1,x
         STA $81
         RTS
AddInt:
      LDA $80
      CLC
      ADC $82
      STA $82
      LDA $81
      ADC $83
      STA $83
      RTS

Comp:
         LDA $81
         CMP $83
         BEQ CompLabel
         RTS
CompLabel:
         LDA $80
         CMP $82
         RTS

;*****************************************
CircleReturn:
      PLA
      STA $86
      PLA
      STA $85
      PLA
      STA $84
      PLA
      STA $47
      PLA
      STA $46
      PLA
      STA $45
      PLA
      STA $44
      PLA
      STA $43
      PLA
      STA $42
      PLA
      STA $41
      PLA
      STA $40


CircleReturn1:
      RTS

Circle: STA $300f
      LDA $3004
      CMP #$a0
      BCS CircleReturn1
      LDA $40
      PHA
      LDA $41
      PHA
      LDA $42
      PHA
      LDA $43
      PHA
      LDA $44
      PHA
      LDA $45
      PHA
      LDA $46
      PHA
      LDA $47
      PHA
      LDA $84
      PHA
      LDA $85
      PHA
      LDA $86
      PHA

      LDA $300f
      STA $85                   ;save A in $85
      LDA $3000                ;将圆周上四点的坐标按上下左右的
      STA $40                   ;顺序依次送$40~$47
      STA $42
      TAX
      SEC
      SBC $3004
      STA $44
      TXA
      CLC
      ADC $3004
      STA $46
      LDA $3001
      STA $45
      STA $47
      TAX
      SEC
      SBC $3004
      STA $41
      TXA
      CLC
      ADC $3004
      STA $43             ;*****************************
      LDA $3004
      STA $84          ;index x
      LDA #$00
      STA $86          ;index y
      JSR CircleDraw
      INC $86
CircleLabel1:
      LDA $84
      JSR Power
      LDA $80
      STA $82
      LDA $81
      STA $83
      LDA $86
      JSR Power
      JSR AddInt
      LDA $3004
      JSR Power
      JSR Comp
      BCC CircleLabel2
      INC $86          ;y->y+1
      DEC $40
      INC $42
      INC $45
      DEC $47
      JSR CircleDraw
      JMP CircleLabel1
CircleLabel2:
      DEC $84
      BNE CircleLabel3
      JMP CircleReturn
CircleLabel3:
      INC $41
      DEC $43
      INC $44
      DEC $46
      JSR CircleDraw
      JMP CircleLabel1
CircleDraw:
      LDA $85
      LDX $40
      LDY $41
      JSR PutPoint
      LDA $85
      LDX $42
      LDY $43
      JSR PutPoint
      LDA $85
      LDX $44
      LDY $45
      JSR PutPoint
      LDA $85
      LDX $46
      LDY $47
      JSR PutPoint
      RTS

[此贴子已经被作者于2005-1-10 19:12:22编辑过]

Anson · 发表于 2005-1-12 11:47:00

不错～顶之～～

Eastsun · 发表于 2005-1-12 16:52:00

惭愧,说实话,第一次写这种东西~
对很多东西把握得很不好,有些代码是边想边写,显得很不整洁.
还有,我在想怎么实现将一个图形数据发送到屏幕指定位置时遇到了困难,不知怎样才能高效实现.
那位指教一下,不尽感激~

SAILOR-HB · 发表于 2005-1-13 12:17:00

"怎么实现将一个图形数据发送到屏幕指定位置"
什么意思？一个图形块吗？

Eastsun · 发表于 2005-1-13 12:24:00

对~

Eastsun · 发表于 2005-1-13 20:37:00

第二种算法很不错！

laugj · 发表于 2005-1-14 12:53:00

如何画一个圆........
-_-
表告诉我汇编代码,其他的代码好吗?比如LAVA(不是语句)、BASIC(不是语句)

Eastsun · 发表于 2005-1-14 16:29:00

我用的算法是这样的（假设圆心为（0，0），半径为R）:
现确定圆上四点：X1,Y1;X2,Y2;X3,Y3;X4,Y4的初始值（0，R），（0，－R），（-R，0），（R，0）
LOOP:
   IF  X4==0 RETURN
ELSE:
   A＝X4^2+Y4^2
   IF A>=R^2  GOTO LABEL1
   ELSE GOTO LABEL2
LABEL1:
X3=X3+1
X4=X4-1
Y1=Y1-1
  Y2=Y2+1
GOTO LOOP
LABEL2:
Y3=Y3+1
Y4=Y4-1
X1=X1-1
X2=X2+1
GOTO LOOP
**************************************
简单的说就是从四个点合拢，本来应该从八个方向合拢比较好（每个起始点都同时向两个方向延伸，这样合拢的地方比较平滑）；
但为了简单和节约零叶地址，我就简化了。（这样是有后遗症的，你运行试一下便知），不过我对这个程序要求不高，因为我想不到有程序必须做圆，呵呵

dae · 发表于 2005-1-14 16:39:00

我在只在WQX汇编的！！

郁闷，看得我头晕的！！！

Eastsun · 发表于 2005-1-14 16:44:00

这个，在wqx上直接调试一些中断调用还可以，
想在wqx上直接编一个上k的程序恐怕够呛吧
而且这些东西你看不看懂也无所谓，函数的入口我已经写的很清楚了，会用就行

Eastsun · 发表于 2005-1-14 17:29:00

不会吧？
在wqx上直接移植一个上十K的程序没什么问题，但直接写？？？
即使先在稿纸上把代码写好再抄上去也非易事，何况直接写。
反正我是很难想象～

Lendy · 发表于 2005-1-14 17:54:00

这两个不应算是数十K吧……约75%是原NAND里的Code……
不过，在WQX上写出数十K的BIN文件是有可能的。注意是指BIN文件，而非纯Code。
在WQX上写Code，一般需要事先划分好各段程序的空间（需要预测子程序的复杂度），定下各段程序的起始地址以便JSR/JMP，这样可以提高效率。
当然，就难免会空出其中部分空间，最终的文件也就比Code所占空间要大。

laugj · 发表于 2005-1-14 23:38:00

那个圆的算法我回学校仔细研究一下
请问在汇编中的最快的算法是你给我的那个BASIC代码吗?

		自动登录	找回密码
密码			加入易码